Edit by JMT 2016-08-12

Single-cell formula for a Poisson distribution

The following array formula

{=IF( lambda > 20, INT( NORM.INV( uniform, lambda, SQRT( lambda ))), MATCH( uniform, IF( ROW( $A$1:$A$66 ) = 1, 0, POISSON( ROW( $A$1:$A$66 )-2, lambda, TRUE ))) - 1 )}

will generate an approximate Poisson distribution with mean equal to the value lambda, where uniform is a uniform random number between 0 and 1, such as is produced by Excel’s RAND() function.

How does it work?

The outer IF() function approximates the Poisson distribution with a Normal distribution when the parameter lambda is greater than 20.

The inner expression,

MATCH( uniform, IF( ROW( $A$1:$A$66 ) = 1, 0, POISSON( ROW( $A$1:$A$66 )-2, lambda, TRUE ))) – 1

works as follows:

ROW( $A$1:$A$66 ) returns an array of the row numbers of cells A1 through A66, which is just the numbers 1 to 66. ROW( $A$1:$A$66 ) – 2 then creates an array running from -1, 0, 1, 2, 3, … 64.

The function POISSON( N, lambda, TRUE ) returns the probability that a Poisson random variable, with mean lambda, has a value less than or equal to N.

Therefore POISSON( ROW( $A$1:$A$66 )-2, lambda, TRUE )) returns an array showing the probability that a Poisson distribution with mean lambda has values less than or equal to -1, 0, 1, etc. In effect this is a cumulative distribution function for a Poisson distribution.

The -1 case can never happen, of course, so the inner IF() function replaces it with the value 0, that is, the chance that a Poisson random variable is less than or equal to -1.

Thus we now have a table with the values

1: Chance a Poisson is less than 0 (=0)

2: Chance it’s less than 1

3: Chance it’s less than 2

Etc.

The MATCH() function matches a uniform random variable to this table. It returns the row number with the largest probability on the Poisson CDF Table that is less than or equal to the uniform value. Imagine the uniform is greater than or equal to the value in row 2 and less than the value in row 3. By definition, this happens exactly as often as a Poisson random variable is greater than or equal to 1 but less than 2, that is, as often as the Poisson random variable is equal to 1. (Recall that Poisson random variables can only be whole numbers). The MATCH() function will return the value 2—too large by exactly 1. So we subtract 1 as the final correction to get (almost) a Poisson random variable.

This formula has flaws. It evaluates the POISSON() function 66 times every time it is used, so it is rather slow. And it can never give a value greater than 65, so very rare cases will not be captured. But for many purposes this formula is adequate, and usefully compact.